&НаКлиенте
Процедура Скриншот_сеанса(Полный_путь_к_файлу = "") // доступна с версии 8.3.17

    // Сохранение скриншота текущего сеанса пользователя (по переданному адресу)
    // Установить в настройках БД: "Управление настройками обработки ошибок" -
    // "Снимок окон приложения" = "Отправлять"

    #Если НЕ ВебКлиент Тогда

        // Получаем имя временного файла с типом: Строка
        Временный_zip_файл = ПолучитьИмяВременногоФайла("zip");

        // Регистрация (сохранение и отправки данных) ошибки
        Отчет_об_ошибке = Новый ОтчетОбОшибке(ИнформацияОбОшибке());
        Отчет_об_ошибке.Записать(Временный_zip_файл, Ложь);

        // Получаем имя каталога временных файлов пользователя
        Каталог_файлов = КаталогВременныхФайлов() + СтрЗаменить(Новый УникальныйИдентификатор, "-", "");

        // Чтение файла ZIP
        Архив_zip  = Новый ЧтениеZipФайла(Временный_zip_файл);
        Архив_zip.ИзвлечьВсе(Каталог_файлов, РежимВосстановленияПутейФайловZIP.НеВосстанавливать);

        // Случайное число в диапазоне от 1 до 999999 для рандомного имени файла
        ГенераторСлЧисел = Новый ГенераторСлучайныхЧисел();
        СлучЧисло=ГенераторСлЧисел.СлучайноеЧисло(1,999999);

        // Сохраняем скриншот 1С в папку
        Путь_к_скриншоту = Каталог_файлов + "\screen"+СлучЧисло+".png";
        КопироватьФайл(Путь_к_скриншоту, Полный_путь_к_файлу);

        // Чистим мусор
        УдалитьФайлы(Временный_zip_файл);
        УдалитьФайлы(Каталог_файлов);

    #КонецЕсли

КонецПроцедуры

&НаСервере
Процедура ЗаполнениеРеквизитаФормыДеревоЗначенийИзЗапроса()

    Запрос = Новый Запрос;
    Запрос.Текст =  "ВЫБРАТЬ
    |  Материалы.Ссылка КАК Наименование
    |  Материалы.Родитель КАК Родитель
    |ИЗ
    |  Справочник.Материалы КАК Материалы
    |УПОРЯДОЧИТЬ ПО
    |  Наименование ИЕРАРХИЯ
    |ИТОГИ ПО
    |  Родитель";

    //Внимание! Если правильно не указать вид обхода результата выборки по запросу,
    //то мы получим обычную таблицу значений
    ДеревоЗначений = Запрос.Выполнить().Выгрузить(ОбходРезультатаЗапроса.ПоГруппировкамСИерархией);

    // Заполнение дерева значений из результата запроса
    // колонка "Материалы" – это элемент справочника, колонка "Родитель" – это группа
    ЗначениеВРеквизитФормы(ДеревоЗначений, "ДеревоЗначНаФорме"); // Преобразование в реквизит формы (табличное поле)

КонецПроцедуры

&НаСервере
Процедура ПоискСтрокиВДеревеЗначений() // найдём 1-ю строку со значением «Элемент №1» в дереве значений

    // Преобразование реквизита формы в объект прикладного типа ДеревоЗначений
    ДеревоЗначений = РеквизитФормыВЗначение("ДеревоЗначНаФорме");

    // Поиск строки... (если строка не найдена, вернёт "Неопределено")
    НайденнаяСтрокаДЗ = ДеревоЗначений.Строки.Найти("Первый (вложенный) элемент", "Наименование", Истина);

    // Анализ результата поиска
    Если НайденнаяСтрокаДЗ = Неопределено Тогда
        Сообщить("Строка не найдена");
    Иначе // вренёт первую найденную строку
        Сообщить("Найдена: "+НайденнаяСтрокаДЗ.Наименование + " (" + НайденнаяСтрокаДЗ.Родитель.Наименование + ")");
    КонецЕсли;

КонецПроцедуры

&НаКлиенте
Процедура СверткаВсегоДереваЗначенийНаФорме()

    // ДеревоЗначНаФорме - на форме
    КоллекцияЭлементовДерева=ДеревоЗначНаФорме.ПолучитьЭлементы();
    //Свернуть дерево
    Для Каждого СтрокаКоллекции Из КоллекцияЭлементовДерева Цикл
        ИдСтроки=СтрокаКоллекции.ПолучитьИдентификатор();
        Элементы.ДеревоЗначНаФорме.Свернуть(ИдСтроки); // Сворачиваем каждую строку тут
    КонецЦикла;

КонецПроцедуры

&НаСервере
Процедура СозданиеШаблонаНастроекВторогоФактораАутентификации() // кнопка в обработке

  ШаблонНастроек = ШаблоныНастроекВторогоФактораАутентификации.СоздатьШаблон();

  ЗапросHTTP = Новый HTTPЗапрос;
  ЗапросHTTP.АдресРесурса = "&host"; //в этот параметр на следующем шаге запишется адрес куда отправлять HTTP запрос
  ЗапросHTTP.УстановитьТелоИзСтроки("Ваш код &secret","utf-8"); //тут можно изменить текстовку, обязательно ставим кодировку

  ШаблонНастроек.HTTPЗапросНаАутентификацию = ЗапросHTTP;
  ШаблонНастроек.МетодHTTPЗапросаНаАутентификацию = "POST"; //тут или GET, или POST,
 //я в дальнейшем буду запрашивать пароли через POST
  ШаблонНастроек.Имя = "ИмяШаблона"; //задаем имя шаблона, который используем в дальнейшем для назначения пользователю

  ШаблонНастроек.Записать();

  // Ставим галочку в конфигураторе у пользователя
  // (Администрирование->Пользователи->ищем кому поставить) "Аутентификация токеном доступа"

КонецПроцедуры

&НаСервере
Процедура НазначениеШаблонаВторогоФактораАутентификации()

  Пользователь = ПользователиИнформационнойБазы.НайтиПоИмени("ИмяПользователя"); //ИмяПользователя - меняем на имя пользователя
  НастройкаВФА = Новый НастройкаВторогоФактораАутентификации;
  НастройкаВФА.ИмяШаблонаНастройки = "ИмяШаблона"; //Имя шаблона задавали на 1-ом этапе

  ПараметрыНастройки = Новый Соответствие;
  ПараметрыНастройки.Вставить("host","http://"127.0.0.1/otpavkod/hs/sendpass/?tel=123456789"); //Задаем адрес на который будет отправлен HTTP Запрос с кодом для авторизации
  НастройкаВФА.Параметры = ПараметрыНастройки; //Задаем значение настройки

  МассивНастроек = Новый Массив;
  МассивНастроек.Добавить(НастройкаВФА); //задаем массив настроек, тут важно, что это массив, а значит можно указать несколько настроек аутентификации

  Пользователь.НастройкиВторогоФактораАутентификации = МассивНастроек; //Устанавливаем настройки пользователю
  Пользователь.ОбработкаНастроекВторогоФактораАутентификации = ТипОбработкиНастроекВторогоФактораАутентификации.ИспользоватьСледующуюПриОшибке; //что делать при некорректном вводе кода
  Пользователь.Записать();

КонецПроцедуры

&НаСервере
Процедура ЧтениеИЗаписьФайлов()

    // Любое сериализуемое значение (массив, структура, таблица значений, строки...) можно сохранить в файл
    НаборСимволов = Новый Массив;
    НаборСимволов.Добавить(125);
    НаборСимволов.Добавить("А");
    НаборСимволов.Добавить("99");
    НаборСимволов.Добавить("%");
    ЗначениеВФайл("D:\Symbol.txt", НаборСимволов); // работает только на &НаСервере

    // Восстановление произвольных значений из файла
    НаборСимволовИзФайла = ЗначениеИзФайла("D:\Symbol.txt");
    Сообщить(НаборСимволовИзФайла[0]); // 125
    Сообщить(НаборСимволовИзФайла[1]); // А
    Сообщить(НаборСимволовИзФайла[2]); // 99
    Сообщить(НаборСимволовИзФайла[3]); // %

    // Запись текстового файла (работает и на &НаСервере и на &НаКлиенте)
    // Параметры: Путь с именем файла, кодировка, разделитель строк (необяз.), перезаписывать файл (необяз.)
    ТекстФайл = Новый ЗаписьТекста("D:\Prostokvashino.txt", КодировкаТекста.ANSI, Символы.ПС, Ложь);
    ТекстФайл.ЗаписатьСтроку("Кот Матроскин");
    ТекстФайл.ЗаписатьСтроку("Дядя Федор");
    ТекстФайл.ЗаписатьСтроку("Шарик");
    ТекстФайл.Закрыть();

    // Чтение текстового файла (работает и на &НаСервере и на &НаКлиенте)
    // Параметры: Путь с именем файла, кодировка, разделитель строк (необяз.), монопольный режим (необяз.)
    ТекстФайл = Новый ЧтениеТекста("D:\Prostokvashino.txt", КодировкаТекста.ANSI, Символы.ПС, ,Истина);
    Пока Истина Цикл // По строкам файлам
        СтрокаФайла = ТекстФайл.ПрочитатьСтроку();
        Если СтрокаФайла = Неопределено Тогда
            Прервать;
        Иначе
            Сообщить(СтрокаФайла);// Вывод строки на экран
        КонецЕсли;
    КонецЦикла;

КонецПроцедуры

&НаКлиенте
Процедура ОперацииНадФайлами(Команда)

    // Создание переменных (имя и путь к файлу)
    ПутьКФайлу_Test="D:\Test.txt";
    ПутьКФайлу_Copy="D:\Copy.txt";

    // Создание пустого файла
    ТекстФайл = Новый ЗаписьТекста();
    ТекстФайл.Закрыть();

    // Проверка на существование файла
    ТекстФайл = Новый Файл(ПутьКФайлу_Test);
    Если ТекстФайл.Существует() Тогда
        Сообщить(ПутьКФайлу_Test+" существует!");
    КонецЕсли;

    // Копирование файла. Параметры: Какой файл копируем, Куда файл копируем
    КопироватьФайл(ПутьКФайлу_Test, ПутьКФайлу_Copy);// Если файл существует, то перезапишет

    // Перемещение файла. Параметры: Какой файл копируем, Куда файл копируем
    ПереместитьФайл(ПутьКФайлу_Test, ПутьКФайлу_Copy);// Если файл существует, то перезапишет

    // Поиск файлов в каталоге (функция возвращает массив значений)
    // Параметры: Каталог поиска, Маска поиска, Поиск и в подкаталогах
    МассивФайлов = НайтиФайлы("D:\", "*.txt", Ложь);
    Для Каждого ТекФайл Из МассивФайлов Цикл
        Сообщить("Найден файл: " + ТекФайл.ПолноеИмя);
    КонецЦикла;

    // Удаление файла
    УдалитьФайлы(ПутьКФайлу_Test); // Если файл с параметром только для чтения, то будет ошибка

    // Удаление файлов в каталоге по маске
    // поиск в каталоге нерекурсивный
    УдалитьФайлы("D:\","*.txt"); // Если маски нет, то удалятся все файлы и сам каталог

    // Получение имя временного файла
    ПолучитьИмяВременногоФайла(); // Например, C:\Temp\H_kImX035.tmp
    ПолучитьИмяВременногоФайла(".txt"); // Например, C:\Temp\H_kImX035.txt

КонецПроцедуры

&НаКлиенте
Процедура ПолучениеИИзменениеАтрибутовФайла(Команда)

    ТекстФайл = Новый Файл("D:\Test.txt");

    // Чтение атрибутов
    ТекстФайл.ПолучитьВремяИзменения(); // время последнего изменения файла
    ТекстФайл.ПолучитьТолькоЧтение();  // проверяем атрибут только чтение
    ТекстФайл.ПолучитьНевидимость(); // проверяем атрибут hidden (скрытность, невидимость)
    ТекстФайл.Размер(); // размер файла в байтах

    // Получение расширение файла из его пути
    ТекстФайл.Расширение(); // .txt

    // Получение имени файла без расширения
    ТекстФайл.ИмяБезРасширения(); // Test

    // Получение информации по пути файла - это файл или каталог
    Если ТекстФайл.ЭтоКаталог() Тогда
        // Это каталог
    ИначеЕсли ТекстФайл.ЭтоФайл() Тогда
        // Это файл
    КонецЕсли;

    // Изменение атрибутов
    ТекстФайл.УстановитьВремяИзменения(ТекущаяДата()); // меняем время последнего изменения файла
    ТекстФайл.УстановитьТолькоЧтение(Ложь); // меняем атрибут только чтение
    ТекстФайл.УстановитьНевидимость(Ложь); // меняем атрибут невидимости

КонецПроцедуры

&НаКлиенте
Процедура ОперацииНадКаталогами(Команда)

    //Создание каталога (он может уже существовать)
    СоздатьКаталог("D:\Catalog");

    //Создание подкаталогов
    СоздатьКаталог("D:\Catalog\2020\1");

    // Проверка существования каталога
    Каталог = Новый Файл("D:\Catalog");
    Если Каталог.Существует() Тогда
        Сообщить("Каталог по пути D:\Catalog существует!");
    КонецЕсли;

    // Удаление каталога (вместе с файлами и подкаталогами)
    УдалитьФайлы("D:\Catalog"); // Можно добавить максу

    // Получение каталога временных файлов
    КаталогВременныхФайлов(); // Например, C:\Windows\Temp

КонецПроцедуры

Функция ПолучитьДвоичныеДанныеОбъекта()

   // Получение двоичных данных через временный файл (и помещение их во временное хранилище)
   ВременныйФайл = ПолучитьИмяВременногоФайла("SCAN");
   ТабличныйДокумент.Записать(ВременныйФайл, ТипФайлаТабличногоДокумента.PDF);
   АдресВоВременномХранилище = ПоместитьВоВременноеХранилище(Новый ДвоичныеДанные(ВременныйФайл));

   // Получение двоичных данных через временный файл (и помещение их во временное хранилище)
   Поток = Новый ПотокВПамяти;
   ТабличныйДокумент.Записать(Поток, ТипФайлаТабличногоДокумента.PDF);
   АдресВоВременномХранилище = ПоместитьВоВременноеХранилище(Поток.ЗакрытьИПолучитьДвоичныеДанные());

   Возврат АдресВоВременномХранилище;

КонецФункции

&НаКлиенте
Процедура ПередачаФайлаСКлиентаНаСервер(Команда)

    ТекстФайл = Новый ЗаписьТекста("D:\Prostokvashino.txt");
    ТекстФайл.ЗаписатьСтроку("Кот Матроскин");
    ТекстФайл.ЗаписатьСтроку("Дядя Федор");
    ТекстФайл.ЗаписатьСтроку("Шарик");
    ТекстФайл.Закрыть();

    Завершено = Новый ОписаниеОповещения("ПослеПередачи", ЭтотОбъект);

    // Параметр УникальныйИдентификаторФормы - если не указывать - то файл будет удален после очередного запроса сервера
    // если указать - то после удаления объекта формы
    // Параметр Интерактивно (Истина) - дает пользователю выбрать файл самому
    НачатьПомещениеФайла(Завершено, , "D:\Prostokvashino.txt", Ложь, ЭтаФорма.УникальныйИдентификатор);

КонецПроцедуры

&НаКлиенте
Процедура ПослеПередачи(Результат, ХранимыйАдрес, ВыбранноеИмяФайла, ДопПараметры) Экспорт

    Если Результат Тогда
        // Сохранение полученного адреса в реквизите формы (строка) - адрес файла в хранилище на сервере
        АдресФайлаВХранилище = ХранимыйАдрес;
        Сообщить("Файл " + ВыбранноеИмяФайла + " передан на сервер и сохранён во временном хранилище. Адрес: " + ХранимыйАдрес);
    Иначе
        Сообщить("Ошибка передачи файла на сервер!");
    КонецЕсли;

КонецПроцедуры

&НаСервере
Процедура ЧтениеФайлаНаСервереИзВременногоХранилища()

   Если ФайлВХранилище = "" Тогда
       Сообщить("Сначала нужно передать файл с клиента на сервер!");
       Возврат;
   КонецЕсли;

   ДвоичныеДанные = ПолучитьИзВременногоХранилища(ФайлВХранилище);
   Если ДвоичныеДанные = Неопределено Тогда
       Сообщить("Файл уже был удалён из временного хранилища!");
       Возврат;
   КонецЕсли;

   ДвоичныеДанные.Записать("D:\to_test.txt");

   Текст = Новый ЧтениеТекста("D:\to_test.txt");
   Пока Истина Цикл
       Строка = Текст.ПрочитатьСтроку();
       Если Строка = Неопределено Тогда
           Прервать;
       Иначе
           Сообщить(Строка);
       КонецЕсли;
   КонецЦикла;

КонецПроцедуры

&НаКлиенте
Процедура ПередатьФайлССервераНаКлиент(Команда)

    Если ФайлВХранилище = "" Тогда // Реквизит формы (строка): адрес файла в хранилище на сервере
        Сообщить("Сначала нужно сохранить файл на сервере.");
        Возврат;
    КонецЕсли;

    Завершено = Новый ОписаниеОповещения("ПослеПолучения", ЭтотОбъект);

    МассивФайлов = Новый Массив;
    МассивФайлов.Добавить(Новый ОписаниеПередаваемогоФайла("D:\from_test.txt", ФайлВХранилище));
    НачатьПолучениеФайлов(Завершено, МассивФайлов,, Ложь);

КонецПроцедуры

&НаКлиенте
Процедура ПослеПолучения(Файлы, ДополнительныеПараметры) Экспорт

    Для Каждого ТекФайл Из Файлы Цикл
        Сообщить(ТекФайл.Имя + " получен из " + ТекФайл.Хранение);
    КонецЦикла;

КонецПроцедуры

Функция ПолучитьМестоНаДиске(Диск) Экспорт // Диск - строка - "d:\"

   СистемнаяИнфо = Новый СистемнаяИнформация;
   ТипПлатформы = СистемнаяИнфо.ТипПлатформы;

   Если ТипПлатформы = ТипПлатформы.Windows_x86
       Или ТипПлатформы = ТипПлатформы.Windows_x86_64 Тогда

       СкриптФСО  = Новый COMОбъект("Scripting.FileSystemObject");
       МестоНаДиске = Окр(Число(СкриптФСО.getDrive(СкриптФСО.GetDriveName(Диск)).freeSpace())/1024/1024, 2);

       Возврат МестоНаДиске;

   Иначе

       //Сообщить("Данная функция поддерживается только в ОС Windows");
       Возврат  Неопределено;

   КонецЕсли;

КонецФункции